;4 player adapter sample code by gpz/hit
;CGA adapter ASM
;---------------------------------------

joy3reg  = $02  ; example joy-regs
joy4reg  = $03

btemp    = $04  ; temp for display

;---------------------------------------
; main
;---------------------------------------

         *= $1000

         ;
         ; usual irq setup
         ;

         sei
         lda #>irq
         sta $0315
         lda #<irq
         sta $0314
         lda #$1b
         sta $d011
         lda #$7f
         sta $dc0d
         lda #$ff
         sta $d012
         lda #$01
         sta $d01a

         ;
         ; print info
         ;

         ldx #$00
loop     .var *
         lda screen,x
         jsr $ffd2
         inx
         cpx #22
         bne loop

         jsr setup    ; cia setup for adapter

         cli

         jmp *

;---------------------------------------
; interupt calls other routines
;---------------------------------------
irq

         inc $d020

         jsr read   ; read adapter

         inc $d020

         ldx #(40*1)+4
         lda $dc00
         jsr displaybits

         ldx #(40*2)+4
         lda $dc01
         jsr displaybits

         ldx #(40*3)+4
         lda joy3reg
         jsr displaybits

         ldx #(40*4)+4
         lda joy4reg
         jsr displaybits

         lda #$00
         sta $d020

         inc $d019
         jmp $febc

;---------------------------------------
; displays 5 lowest bits of joystick-reg
;---------------------------------------
displaybits

         rol a
         rol a
         rol a

         sta btemp

         ldy #$00
loop     .var *

         rol btemp
         bcc skip1

         lda #"-"
         sta $0400,x
         jmp skip2
skip1
         lda #"*"
         sta $0400,x
skip2
         inx
         iny
         cpy #$05
         bne loop

         rts

;---------------------------------------
screen
         .text "{clr/home}joy brldu"
         .text " 1{return}"
         .text " 2{return}"
         .text " 3{return}"
         .text " 4{return}"

;---------------------------------------

;---------------------------------------
read
;---------------------------------------
; reads adapter and composes the
; additional virtual joystick-registers
;---------------------------------------
;this code demonstrates how to read the
;additional 2 joysticks and how to com-
;pose 2 'virtual' joystick-registers
;that can be processed exactly like the
;usual ($dc00/$dc01) ones.
;---------------------------------------

        lda $dd01       ; cia 2 port B read/write
        and #$1f        ; get bit 4-0 (PB4-PB0)
        sta joy3reg     ; joy 3 complete
        lda #$00        ; cia 2 port B read/write
        sta $dd01       ; (output zero at PB7)
        nop             ; no idea if this delay is needed
        nop
        nop
        lda $dd01       ; cia 2 port B read/write
        and #$0f        ; get bit 3-0 (PB3-PB0)
        sta joy4reg     ; joy 4 directions
        lda $dd01       ; cia 2 port B read/write
        and #%00100000  ; get bit 5 (PB5)
        lsr
        ora joy4reg
        sta joy4reg     ; joy 4 button
        rts

;---------------------------------------
setup
;---------------------------------------
;warning: do not mess around with this
;         unless you really know what
;         you are doing! wrong cia setup
;         may toast your cia's !
;---------------------------------------

        lda #%10000000  ; cia 2 port B Data-Direction
        sta $dd03       ; bit 7: out    bit 6-0: in
        nop             ; no idea if this delay is needed
        nop
        nop
        lda $dd01       ; cia 2 port B read/write
        sta $dd01       ; (output zero at PB7 ?)
        rts

;------------------------------------------------------------------------------